通达信公式教程
供初学者操作指南

公式入门
我们大多数的用户并不是完全了解“公式编辑器”的意义,简单地,我们可以从以下几个角度进行理解:
一、指标分析:
“公式编辑器”好比是一个工作母床,通过这个工作母床可以制造出所需要的各式各样的零件,同样,在指标分析的工作中,利用编辑器可以编写出相应的分析条件,这种方法是在技术分析当中最为常用的方法之一。例如,指标KD、指标MA等等,通过对这些指标的观察、分析,找出一些合适的条件作为买入卖出点。当然,我们也许需要的是一些自己的指标,一些自己的准确的指标,更多的MB、MC、MD等等,这一切我们通过“公式编辑器”可以实现。
二、条件选股:

编写公式都要用到什么东西?
我们留下了许多问题--都是公式编写的基础问题,所以我们这节课来解决这些基础的问题。
什么是技术指标?
MA均线就是一种技术指标,我们在炒股的时候,经常会将一些行情数据进行数学计算得出一些曲线等等,方便我们掌握股市的变动情况。
什么是条件选股?
简单讲,就是按照您的设定的条件用电脑帮助您完成一些太多太复杂的挑选--比如您有一些好的心得和方法,可使有1000多只股票,您就是有100双眼睛有时也不一定可以看得过来,这时电脑就派上用场了!
什么是参数?
比如讲:10日均线,您可以把10日当作参数,好处在于,您觉得需要修改成5日的时候,就可以使用一些简单的方法,例如参数精灵来很方便的修改和调整。参数需要名字,例如M就不错。还要规定参数的范围,例如1日至260日。这样我们就可以在1到260之间任意调节M的值了,M最常用的数填在“缺省”一栏,例如你最喜欢用10日均线,那就填10吧。
什么是周期?
这么解释吧!我们有的投资者喜欢使用日线图作技术分析;有的喜欢用5分钟的K线;有的喜欢使用长一点时间的,例如周线。所以在公式设计中,允许不同喜好的使用者选择不同的分析时间--就是可以选择不同的周期。
什么是函数?
函数在公式编写非常重要,如果作个比喻,我们用一种语言去告诉电脑我的想法,并且让它去帮我做,那么函数就是这种语言的单词。
我们在公式编辑器中选择插入函数,就可以看到里面有许多的函数,我们在附录中有一个简表,大家可以到那里去检索!
例一:
一根K线有四个价格组成:
最高价:HIGH
收盘价:CLOSE
最低价:LOW
开盘价:OPEN
成交量:VOL
成交额:AMO
例二:
两条均线不断地交叉,就专门设定了一条函数来描述两条线交叉:CROSS(X,Y)
假如下图中的两条均线一条名叫X,另外一条叫Y
CROSS(X,Y)表示X向上穿过了Y
CROSS(Y,X)表示Y向上穿过了X
例三:
前面的CLOSE,还是VOL,都表示当天,或者您使用的不是日线,那就表示本周期的数据,那么前几天的怎么表示呢?
REF(X,M)
例如:
REF(Close,5)表示5天前的收盘;
REF(Vol,10)表示10天前的成交量;
这里的M就是参数,您现在明白了什么是参数了吗?
例四:
如果我想把两个条件并列在一起怎么办?
AND
X AND Y就表示条件X和条件Y
好了!本课结束吧--有点稍慢,下面会好一些!
编写一条最简单的指标线
通过前几课的学习,我们今天开始使用软件的公式编辑功能编写我们自己的第一条指标线。
其实不难,你应该对自己有信心!
按照主菜单-工具-公式管理-选择-“技术指标”-点击“新建”,然后在公式编辑器中留下你的第一行脚印吧!
点击:“确认”,现在看一下我们第一条指标线。
这条指标线与你的想法相符吗?
总结与补充:
1、如果选择:“主图叠加”,我们的指标线会与K线图显示在同一个图形框中,现在我们的指标线显示在其下方,即“副图”中;
2、参数可以有,也可以没有,但是鼓励大家设置参数,这是非常好的习惯;
3、一个句子完了,别忘了以分号结尾;
你的公式写得对不对,可以通过“测试公式”来检查,如果错了,它会告诉你错在哪里。

编写最常用的均量和均价线
均价线,不就是那个“移动平均线MA”什么的吗?不过,话说回来,听说10个人里面有11个人都在使用,我可得学习学习!
原理是??
5日平均线=(今天收盘价+昨天收盘价+.....--5天前的收盘价)/5;
10日平均线=(今天收盘价+昨天收盘价+......+10天前的收盘价)/10;
150日平均线=(今天收盘价+昨天收盘价+......+150天前的收盘价)/150;
200日平均线......不是这么麻烦吧?难道我每天都要写这么多得数才得到一条平均线????
你有什么办法?
MA1=MA(CLOSE,5);
MA2=MA(CLOSE,10);
MA3=MA(CLOSE,50);
......
当然是有简单的方法了!你把我在上面说过的话写下来,按照前面几课讲的,写在公式的编辑栏当中就可以了!
注意:
“MA”表示的就是计算平均值。
在括号内写上计算的对象和计算的时间长度。
MA1,MA2,MA3......是好几条指标线,别忘记了用分号把它们分开。
最后呢?电脑自己会把它们一起画出来。
均量线???
均价线都有了,照着葫芦画瓢,把收盘价CLOSE换成成交量VOL就行了!
MA1:MA(VOL,5);
MA2:MA(VOL,10);
MA3:MA(VOL,150);
MA4:MA(VOL,200);
今天有几只发生MA金叉?
我们学习了编写MA移动平均线,关于这几条指标线如何使用?我想大家可能都比我清楚。例如短期均线和长期均线发生了金叉或者死叉,......等等,葛兰维尔的八项法则......如果说如何用软件编写一个条件,让电脑把今天两个市场的股票中所有发生了黄金交叉的股票选出来呢?
想知道吗?这就是“条件选股”,按照“条件”电脑自动“选择股票”出来,可以供您分析,要不然的话,技术分析的投资者都会累死了!
跟我学!
第一步:“工具”栏中选中“公式管理器”
第二步:我们现在选择“新建”一个“条件选股”公式,结果出现了下面的编辑栏!然后在里面写上您的条件!
第三步:按照说明书上的步骤选股就行了!
注意:
1、在条件选股中点击“新建”;
2、原来MA5:MA(CLOSE,5);
表示的是一条指标线,可是现在我们在条件选股当中只要引用它,不需要把它画出来。所以我们在冒号的后面加一个符号,表示等会要引用它:MA5:=MA(CLOSE,5);
这个在的公式编辑中,叫做“中间表达式”。
X=1;
Y=X+1;
Y=?
我们学过上面的数学,都知道把X=1代入到Y的计算中去,“X=1;”就是一个中间表达式,您明白了吗?

条件选股总结:
1、指标和条件选股在结构上没有差别,只是在内容上,条件选股要多加上我们的条件,比如大于10,或者交叉等等!
2、中间表达式可以帮助我们清晰的表达我们的公式,不至于使公式的结构特别的混乱!

如何编写BIAS指标?
如果大家都是均线的忠实爱好者的话,那么大家一定牢牢记得在均线大师哥南威尔的8大法则当中的第四条和第五条中曾经提到了当股价偏离均线太远的时候,便会向它靠拢,但是并不提到多远才会靠拢--为了解决这个问题,也为了我们更好地用客观数据来体现股价运动的过程,乖离率这个指标应运而生。
本课我们的任务就是通过对乖离率的原理到编写方法的学习来加强我们对公式设计的理解。
首先,什么是乖离率?
以当日的均线价格为准,股价和均价之间的差距称为乖离程度,以乖离程度除以均价的百分比就是乖离率。
当日股价与10日均线的乖离率=(当日股价-10日均价)/10日均价*100;
当日股价与20日均线的乖离率=(当日股价-20日均价)/20日均价*100;
当日股价与30日均线的乖离率=(当日股价-30日均价)/30日均价*100;
原理就是这么简单,可是怎么使用呢?您别急,所用的指标其实都是在观察当中得出一定的启示,您先实现这几条指标线,让它们以图形的方式出现在您的面前,然后您再去观察,一定会事半功倍!
比如编写10日乖离率
第一步:乖离率的命名,崇尚人家的习惯,依旧使用BIAS,那么第一条就叫做BIAS1好了!
第二步:当日股价用CLOSE表示;
10均价我们在前一节课刚刚学过,顺手拈来,用MA(CLOSE,10)表示;
第三步:一样使用加减乘除符号以及括号,只是要注意只有小括号,没有中大括号,那么公式就有了--
BIAS1:(CLOSE-MA(CLOSE,10))/MA(CLOSE,10)*100;
这样的话我们在技术指标编辑器中将另外两条指标也同样写下来,就得到了BIAS指标,请看下图:
第四步:就是您得自己好好观察您的指标公式在各个股票的表现,得出您自己的结论,因为每一个投资者即使是在使用同样一个指标的时候,都会有不同的理解,我们无法判断优劣,但是有一条可以告诉我们答案,那就是永远让市场说话,因为它永远是对的!
如果您不介意的话,可以参考BIAS,不过仅供参考!
您明白怎么编写了吗?我能不能直接用写好的指标公式?
我想用KD指标选股,能不能直接写成“D>20”就可以执行了?
当然可以!考虑到了这种偷懒的做法,所以我们一共提供了两种供偷懒的人士使用,其中一种与上面的要求只是在写法上稍有不同!
第一个方法:
第一步:在条件选股的编辑器中点击“引入指标公式”。
引入“其他公式”。然后,我们从中选择一个,例如“KD”,让我们来看一下结果如何?
第二步:上一步的操作结果请看右边的图形,系统自动的把KD指标的整个编写内容搬来了!
现在需要我们做的就是:续上一行条件“D<20”,OK!完成!
有没有简单的方法?
第二个方法:就一句话:“KDJ,D”<20;
“KDJ,D”
表示现在我要是用KDJ指标当中的D指标,不过大家要看清楚是怎么写的哦!写错了计算机可是不会改错的!
总结:
用上面的方法可以引用所有指标,所以不必写那么多!
注意格式上,两边用引号括起来,指标名称KDJ和指标线名称D之间用“,”隔开!

额外加餐
现在我们可以很方便的做另外一件事了,我们可以将通常说的KDJ买入条件完整的表达出来了:
“KD指标发生了黄金交叉,并且D<20”
T1:=“KDJ,K”;--引用K线;
T2:=“KDJ,D”;--引用D线;
条件: AND在中就表示“并且”,将两个条件并列起来
CROSS(T1,T2)ANDT2<20;

第九课 放量、缩量、上涨、下跌、收阳、收阴
在前面的学习当中,我们见到了一些基本的表达方法、方式,今天我们的任务是学习一些常见的概念如何编写,例如上面所列出来的放量、上涨等等,因为这些都是在公式编写过程当中要用到的基本的小的形态特征,许多的技术指标的选股条件都是由它们组成的。
放量:
1、今日比昨日的成交量放大了1倍:
VOL/REF(VOL,1)>2;
2、今日的五日均量比前五天的五日均量放大了3倍:
AA:=MA(VOL,5);
BB:=REF(AA,5);
AA/BB>4;
3、今天的成交量达到了整个流通盘的10%以上:
VOL/CAPITAL>10/100;
(注意,10%的表达式是10/100,或者0.1)
缩量:
1、今日比昨日的成交量缩小了1倍:
VOL/REF(VOL,1)<0.5;
2、今日的五日均量比前五天的五日均量缩小了一半:
AA:=MA(VOL,1)<0.5;
BB:=REF(AA,5);
AA/BB<0.5;
3、今天的成交量不足整个流通盘的0.5%:
VOL/CAPITAL<0.5/100;
上涨:
1、今日涨幅达到了7%以上:
CLOSE/REF(CLOSE,1)>1.07;
2、十日均价继续上涨:
AA:=MA(CLOSE,10);
BB:=REE(AA,1);
AA>BB;
下跌:
同上面的表达方式一样,将方向改变了而已:
收阳、收阴:
1、当天收阳:CLOSE>OPEN;
2、当天收阴:CLOSE<OPEN;
高开、低开:
1、当天股价高开,言下之意开盘高于昨日收盘:OPEN>REF(CLOSE,1);
2、当天股价低开:OPEN<REF(CLOSE,1);
跳空:
跳空亦有向上和向下两种:
当日开盘在昨日最高之上,即为向上跳空:OPEN>REF(HIGH,1);
反之,开盘小于昨日的最高价,为向下跳空:POEN<REF(LOW,1);
事实上,我们在编公式的过程,就是将这些条件有机地结合起来作为我们判断的条件。举一个很简单的例子,如果是K线形态呈现出放量上攻的态势,那么如何编写这个公式呢?高开高走又应该如何编写呢?
我们把放量和上涨的两个条件组合在一起,让某一天的形态特征同时满足两个条件就达到目的;同样地将高开的高走两个条件结合在一起,也就找到了我们所需的条件。
结果就是:
放量上攻之一,以上面所举例组合:
AA:=VOL/REF(VOL,1)>2;
BB:=CLOSE/REF(CLOSE,1)>1.07;
AA AND BB;
高开高走:
AA:=OPEN>REF(CLOSE,1);
BB:=CLOSE>OPEN;
AA AND BB;
OK!本课到此结束,留下一个问题,看看您有没有真正的理解,向上跳空之后两天内并未回补如何编写呢?
提示:实际上就是昨天发生了跳空缺口,这两天的最低价一直在两天前的最高价之上。
AA:=REF(OPEN,1)>REF(HIGH,2);
BB:=REF(LOW,1)>REF(HIGH,2);
CC:=LOW>REF(HIGH,2);
AA AND BB AND CC;
仔细一想,若BB成立,AA一定成立,AA实际上没有存在的必要,你想通了吗?
更简单的方法,下面的一句话可以的上面的四句:
COUNT(LOW>REF(HIGH,2),2)=2;
第十课 涨停板攻击?
学了这么多了,应该教点实战的内容了!我们来学习一下别人的经验,“涨停板追击”,同时这里面还润孕育着一个简单但是又颇有意义的道理!
一、量化的概念
我们都知道,按规定涨幅不得超过10%,但是由于四舍五入的关系,常常有9.98%、10.23%等等的涨停板,所以我们要找一个合适的数值,然后用公式语言告诉计算机,这个过程学名叫量化!
比如我们考察之后,决定让大于9.99%的都为涨停。
二、编写公式
其实就一句话:今日收盘除以昨日收盘的值大于1.0999
X:=CLOSE/REF(CLOSE,1)>1.0999;
三、测试我们的条件
大家都知测试的功能,要不然你怎么知道你的经验在历史上的表现是好还是不好呢?
按照下图指引进入条件选股的界面,之后选中您的条件,具体办法请参见(使用说明书)。然后填入测试时间和测试标准!
在这里我们的测试方法是:
测试时间是从2000/01/01到2001/03/02,测试股票共计583只,初始投入100,000元。
当满足买入公式中定义的条件时,也就是涨停板时,按照收盘价使用相同资金买入一只股票,当满足以下平仓条件时按照收盘价平仓;买入5日后强制平仓或者亏损达到3%止损平仓或者利润达到5%止赢平仓,然后按照以上的规则统计在测试的时间段内的所有交易的状况。
这是一种追涨的短线方法,所以测试的时间我们只用5天,目标利润为5%,(非常抱歉,因为其中的设置和选择方法十分灵活而且需要较好的理解能力,所以我们在这里就不介绍具体的内容了)
点击开始测试!一切OK!来看结果吧!
1、从成功率上看,实际达到5%的获利要求的交易次数67.89%,我们已经比较满意这个结果了,可是要用于实战,可不可以再提高呢?
2、所谓的提高就是优化的一个内容,简单说,优化就是让它更好!优化我们的条件,让它的表现更好!
3、加上一个缩量的条件,比如当日成交量小于5日的均量;Y:=VOL<MA(VOL,5);大家可以做一下测试,看看结果如何!以下是同样测试条件下的结果。 X AND Y;
您满意吗?我们的成功率已达到了80%,剩下的任务就是您如何操作的问题了!
注:请大家考虑一下在实战当中,如果您按此买入可不可行?
总结:编写公式并不是为了编公式而编写复杂的公式,您个人对某一个特征或者形态的理解最重要。所以光有经验不够,您还得把它转化成您自己的应对策略!您需要不断总结、测试、优化您的公式。

第十一课 多头排列--良好的上升趋势
均线的多头排列一直以来都被大家视为一种良好的上升趋势的表现,因为这种形态的形成需要较长的时间,和较大的能量,而被主力或者庄家利用作为骗线的可能性就比较小,股市当中也遵循惯性的原理,当一个趋势形成之后,要改变它,是不容易的,因为股价有着沿着原来的运动方向上的惯性!
首先,让我们来看看几种多头排列:
5、10、30日均线:5、10、30日均线:30、60、90日均线:
在图一中和图二中我们采用的是同一周期的均线,即都是5、10、30日均线,我们可以观察到在同一周期下的均线排列有相同之处,也有很大不同之处:图一中的5日均线=10日均线、30日均线平滑优美,而在图二中的5日和10日均线不断的碰及30日均线然后上升;
在图三中我们选用的是30、60、90日均线,相对来说均线的多头排列也显得很平滑。
为什么会有这样的差别呢?如果您要是认真一点的话,就可以发现原来前两图的K线走得不一样,一个一波拉到头,一个分成几波拉到头,而在图三当中我们采用了较长周期的均线系统,从而在一定程度上过滤了这种现象,具体在使用的过程中,您可要多注意它们的区别!
好了,我们来看一下如何编写,拿第一个为例,观察它们的特征:
5/10/30日均线依次从上而下的排列,这种情况维持一段时间,假设我们这里定为4天以上:
5/10/30日均线依次从上而下的排列:
AA:=MA(CLOSE,5);
BB:=MA(CLOSE,10);
CC:=MA(CLOSE,30);
T1:=AA>BB AND BB>CC;
以上情况维持一段时间,假设我们这里定为4天以上:
COUNT(T1,4)=4;
COUNT(X,N)表示统计在N天内满足条件X的有几天。
最终的结果就是如下所示:
AA:=MA(CLOSE,5);
BB:=MA(CLOSE,10);
CC:=MA(CLOSE,30);
T1:=AA>BB AND BB>CC;
COUNT(T1,4 )=4

编写完毕,我们在上面的例子当中,举的是最简单的一个,其实您在编写的过程当中,还可以加上一些比较准确地描述,以取得更好的效果,例如同时三条均线向上发散等,当然还有您自己的心得。
第十二课 逃顶K线形态之--黄昏之星
一、概念学习
当市场出现一条大阳线后,通常会产生跳空高开的情况,有时便会出现十字星或类似十字星的小阴线(小阳线)。另一种相反的情况是出现在一条大阴线后,在这两种情况下形成的类似十字星的K线都被称为“星型线”。
当该形态出现在一段上升行情的当中,就很容易形成所谓的经典K线形态--黄昏之星。
二、编制过程
通过我们前面的学习,其实已经可以比较轻松的编制这个条件了--前人已经清晰地把这个形态的具体特征描述出来,剩下的工作就是把这些特征用数字表示--这就是前面提到的量化的过程!
该图组合一共由三根K线合成,我们按照以下的步骤一步一步地一边寻找每日K线的特征,一边进行编写:
为了结构简单起见,首先将二天的高开低收用中间表达式表达出来,因为我们在后面的编写过程中会分别使用到这些数据。
1、今日K线的:开-a1, a1:=open;
收-a2, a2:=close;
高-a3, a3:=high;
2、昨天K线的:开-b1, b1:=ref(open,1);
收-b2, b2:=ref(close,1);
高-b3, b3:=ref(high,1);
低-b4, b4:=ref(low,1);
3、前天K线的:开-c1, c1:=ref(open,2);
收-c2, c2:=ref(close,2);
高-c3, c3:=ref(high,2);
低-c4, c4:=ref(low,2);
4、我们将会分别描述出三天的K线形态,然后汇总,首先我们观察今日K线的特征,今天是一根低开低走的大阴线,我们给它一些数字上的定义:
a、今日开盘价小于昨日收盘价; aa:=a1<b2 and
b、今日的阴线实体较长,我们用开盘价和收盘价相比,长度大于4%:a1/a2>1.04;
5、昨日K线的特征,是一根十字形态的K线,并且在左右两根K线之上,分别表达为:
a、昨日跳开,高于前天的收盘: bb:=b1>c3
b、昨日收盘同样在缺口之上: and b2>c3
c、线形实体长度很小,也就是昨日开盘和收盘之差比昨日开盘的值小于0.01:and abs(b1-b2)/b1<0.01
d、K线有上下影线,可以表示为最高价和最低价不等于收盘价也不等于开盘价:and b3>b1 and b3>b2 and b4<b1 and b4<b2
e、当日的最高价为20天以来的最高价: and b3=hhv(high,20);
6、前日K线的特征:股价大幅上扬,幅度较前一日收盘高出4%并且收盘大于开盘:cc:=c2/ref(close,3)>1.04 and c2>c1;
综合选股条件:最后我们将三天的K线特征会合起来,合成一个最后的条件就是由图所示内容: aa and bb and cc
三、选股的结果
我们把上面的条件按照前面章节所讲的方法带入到公式选股条件当中去检验。
按下图作为标准
四、总结
其实到底是难还是不难呢?其实不难,只是你要细心一点把一个一个的条件组合起来,有机地结合起来!我们的许多形态就是这样由一个一个的K线组合起来的结果!
1、我们测试了将近4年的时间,一共找到了几个这样的信号,您满意吗?--应该说,不满意!可是原因在哪里呢?--我们的条件过于苛刻,因为要同时满足的条件太多,您可以尝试更改一些条件以获得更多的信号!
2、大家还会发现有的信号出现的位置不好,例如西飞国际,因为我们其中有一个条件不是很好,不过您可以做到将它去掉--告诉我您可以做到,算是课后作业吧,我看相对高位dd:=b3=hhv(high,20),怎么看都不舒服,您有什么办法?
突破底部横盘整理创新高!
“横的越长,竖的越高”,业内业外一直流传这样一句话。真实的讲,它描绘了股票的价格在一定的范围上下波动,如果有庄家主力在其中悄悄吸纳......直到某一天股价一鹤冲天!沉寂时间越长,爆发力越惊人!
正所谓“三年不鸣,一鸣惊人”......
公式编写:
我们寻找各种特征,并用数字表示出来:“长期”设定为150天;“横盘”设定股价在150日均线上下15%波动;放量;并且股价创下150天以来的历史新高!
1、首先用公式描述放量
a、将会使用5日均量来进行比较,成交量比昨日成交量放大两倍;
b、V1是五日均量,REF(V1,1)就是昨日的均量;
V1:=MA(VOL,5); V2:=VOL/REF(V1,1)>2;
2、长期横盘
a、PZ1是当天150日均价: PZ1:=MA(CLOSE,M);
b、PZ2是150日的最高价; PZ2:=HHV(HIGH,M);
c、PZ3是150日的最低价; PZ3:=LLV(LOW,M);
d、PZ4是150日的最高价和150日均价的距离的百分比,PZ5刚好相反是最低价和均价的差的百分比; PZ4:=(PZ2-PZ1)/PZ1; PZ5:=(PZ1-PZ3)/PZ1;
e、设为股价在150日均线上下15%波动,也就是PZ4、PZ5都小于0.15;
PZ:=REF(PZ4,1)<0.5 AND REF(PZ5,1)<0.15;
3、今天创下历史新高,也就是今天的最高价是150天内的最高价! TP1:HHV(HIGH,M); TP:=HIGH=TP1;
综合三个条件的最后的逻辑判断式就是我们的最后结论! V2 AND PZ AND TP(参数M=150天)

这样,您将上面多写的内容,简单的编入到公式编辑器中去,我们的工作就已经做完了,剩下的测设,大家请按照我们前面所讲的内容去做,只有不断地完善你的公式,把它和实战结合起来,形成您自己的特点的操作体系,您才算是有了自己的武器!
函数介绍:
HHV(X,M)
表示X在M天内的最高值!
例如:
HHV(HIGH,150)每日最高价在150天内的最大值
HHV(VOL,150)每日成交量在150天内的最大值

LLV(X,M)
表示X在M天内的最小值
例如:
LLV(LOW,10)每日最低价在10天内的最小值
HHV(VOL,20)每日成交量在20天内的最小值
好了!
第十课我们也讲完了,我们来回顾一下我们的课程,做一个最后的总结!
事实上,编写公式并不是一件很难的事情!他并不是为编写复杂的公式而在编写公式,恰如孔乙己会写四种回字又有何意义?重要的是您要深刻地理解某一点、某一处--没有人可以全部了解这个市场,可是也很少有人能够潜下心来去想清楚一个问题。
在编写公式的时候,大家一定体会到了,由于计算机的使用给我们带来了巨大的方便,可使计算机并不是完全智能化的,所以它只是一个工具,还有着许多的重要的工作需要人去完成,您千万不能放弃了自己而去迷信一个工具,可能它是您的帮手,但目前来说,无法替代您!您的投资还得由您去做!
《公式教程》公式读书------量能决定趋势

量能动力的分析要点
由于目前市场上的优质上市公司有限,供求关系决定着投资者的盈亏。这样大盘与个股的历史量能、即时量能、潜在量能与市场机会的多寡有着直接关系。一般情况下,大盘的成交量能大机会就多,大盘的成交量能小机会就少,上述情况均与大盘的涨跌无关。
个股的量能决定趋势运行的可靠性,主要公式有:
(1)、量能大+涨得多=继续大涨(适合强势中买进使用)
使用该公式时,注意强势中量比、量能、涨幅榜与开收盘用。
(2)、量能大+涨得少=注意反转(适合强势中卖出使用)
使用该公式时,注意K线的高低位与应用公式。
(3)、量能小+涨得多=注意反转(适合弱势中卖出使用)
使用该公式时,注意与庄股斗法。
(4)、量能小+涨得少=继续小涨(适合盘整势中买进使用)
使用该公式时,注意K线的低位庄股。
(5)、量能大+跌得多=继续大跌(适合弱势中卖出使用)
每年年底这种股票比较多。
(6)、量能大+跌得少=注意反转(适合弱势中买进使用)
使用该公式时,注意K线的高低位与逻辑公式。
(7)、量能小+跌得少=继续小跌(适合弱势中换股使用)
使用该公式时,注意目标股是否减仓。
(8)、量能小+跌得多=注意反转(适合弱势中买进使用)
这种情况是弱势中的天赐良机。

第一步 慨念公式化
上述讲座中提到的名词有:
量能:成交量 函数:vol;
趋势:股价走势 [公式短语]趋势:=100*(close-ref(close,n))/ref(close,n);
强势:趋势向上 [公式短语]趋势>0;
量能大:区间换手率大 [公式短语]sum(hsl,n)>2*n;
量比:今日量与前五日均量之比 [公式短语]100*vol/ma(vol,5);
涨得多:涨幅高 [公式短语] 100*(close-ref(close,n))/ref(close,n)>=1.5*n;
"量能大+涨得多=继续大涨" :[公式短语] 继续大涨:=sum(hsl,n)>=3*n and 100*(close-ref(close,n))/ref(close,n)>=3*n;
"量能大+涨得少=注意反转":[公式短语] 注意反转:=sum(hsl,n)>=3*n and 100*(close-ref(close,n))/ref(close,n)<=n;
"量能小+涨得多=注意反转":[公式短语] 注意反转:=sum(hsl,n)<=0.5*n and 100*(close-ref(close,n))/ref(close,n)>=3*n;
"量能小+涨得少=继续小涨":[公式短语] 继续小涨:=sum(hsl,n)<=0.5*n and 100*(close-ref(close,n))/ref(close,n)<=n;
"量能大+跌得多=继续大跌":[公式短语] 继续大跌:=sum(hsl,n)>=3*n and 100*(close-ref(close,n))/ref(close,n)>=-3*n;
"量能大+跌得少=注意反转":[公式短语] 注意反转:=sum(hsl,n)>=3*n and -n<100*(close-ref(close,n))/ref(close,n)<0;
"量能小+跌得少=继续小跌":[公式短语] 继续小跌:=m(hsl,n)<=0.5*n and -n<100*(close-ref(close,n))/ref(close,n)<0;
"量能小+跌得多=注意反转":[公式短语] 注意反转:=sum(hsl,n)<=0.5*n and 100*(close-ref(close,n))/ref(close,n)<=-3*n;

第二步 公式图形化
量能动力 公式
量能:SUM(HSL,N),NODRAW;
涨幅: 100*(CLOSE-REF(CLOSE,N))/REF(CLOSE,N),NODRAW;
STICKLINE(HSL<=1,HSL,0,1,1),COLORBROWN;
STICKLINE(HSL>1 AND HSL<3,HSL,0,1,0),COLORLIBLUE;
STICKLINE(HSL>=3,HSL,0,1,0),COLORMAGENTA;
继续大涨: DRAWTEXT(量能>3*N AND 涨幅>3*N,HSL,'继续大涨'),COLORRED;
继续小涨: DRAWTEXT(量能<0.5*N AND 涨幅<N,HSL,'继续小涨'),COLORMAGENTA;
继续小跌: DRAWTEXT(量能<0.5*N AND 涨幅>-N AND 涨幅>0,HSL,'继续小跌'),COLORLIGREEN;
继续大跌: DRAWTEXT(量能>3*N AND 涨幅<-3*N,HSL,'继续大跌'),COLORCYAN;
注意反转: DRAWTEXT(((量能>3*N AND 涨幅<N) OR (量能3*N)
OR (量能>3*N AND 涨幅>-N AND 涨幅<0) OR (量能<0.5*N AND 涨幅<-3*N)),HSL,'注意反转'),COLORBLUE;

-----------------------------------------
财务指标的写法!
【市净率】:CLOSE/FINANCE(35),NODRAW;
【市盈率】:CLOSE/(FINANCE(30)/FINANCE(1)/10000),NODRAW;
【换手率】:HSX,VOLSTICK;
【净收益率】:FINANCE(30)/FINANCE(1)/100/FINANCE(34),NODRAW;
【流通盘】:FINANCE(7),NODRAW,NODRAW;
【净资产】:FINANCE(34),NODRAW;
【每股收益】:FINANCE(30)/FINANCE(1)/10000,NODRAW;

---------------------------------------------
均线函数说明
//简单移动平均:MA(X,N)=(X1+X2+X3+...+Xn)/N
//异同移动平均:EMA(X,N),EXPMA(X,N):EMA=(2*X+(N-1)*EMA[i-1])/(N+1)
//平滑移动平均:MEMA(X,N):EMA[N-1]=MA(X,N),MEMA=(X+(N-1)*MEMA[i-1])/N;
//加权平滑平均:EXPMEMA(X,N):EXPMEMA[N-1]=MA(X,N),EXPMEMA=(2*X+(N-1)*EXPMEMA[i-1])/(N+1)
//累积平均:SMA(X,N,P):SMA=(P*X+(N-P)*SMA[i-1])/N
送给爱好公式的股友
公式的作用---送给爱好公式的股友
有学员问我:“公式没什么用----涨三天金叉,跌三天死叉;涨七天超涨,跌七天超跌。公式那么多用什么好?”
目前,我国还没有程式交易咨询公司,公式只停留在娱乐论坛、股评解盘、祖传秘方中,有的软件营销业者将公式商业化到既不可信又好笑的地步,大有狗皮膏药之嫌。有“公式不可信”的观念的人,说明他们在证券分析中,上了一个台阶。前进一步就到了对“操盘方案”的探讨,更进一步就会上到“程式交易”的新天地。公式的作用就如同工具一样,看你怎么用。
例如:有一个操盘方案,短期头寸调整方法为:
换手率< 0.5,买进10%;
RSI(12)< 25,加仓20%;
单日跌5%加仓10%;
换手率> 5,卖出清仓;
没有公式就无法完成买卖。要识别价值高估的股票单个公式还远远不够。因为高估的股票往往同时具有很高的波动性、价量背离、同类股票走势离差大、与大盘相关系数小等等属性。所以不能仅仅停留在玩公式这个层面。把市场内在的运作方式和股票之间历史和理论上的关系编程计算机语言--公式,就是你鱼杆、鱼网,小心呵护,就会带来利润和娱乐。
技术分析派认为:价格是最重要的,其他的因素可以不计;我们现在将股价的变化看成很多自变条件是结果,分析的思维方式变得复杂不堪。有的朋友将七项变量写成一个公式,结果不如20日均线。公式复杂化容易,简单就要用心。用简单地公式做成交易提示,是一件快乐的事。走进了公式误区的朋友,回过头来看看工具的作用,也就理解公式的作用。崇拜思想用于公式是不大合适。
选股-----被股民用来判断股评家水平高低的标准。在目前的情况下,大盘与个股联动强烈的今天,在同类股票中(叠加即可看清楚),选股的意义不大。如:0005、0404、0852、007、买卖时机相同,盈亏比例相近,至于指标、K线形态上的差异就不必细究了。目前有800多只股票与大盘相近,还在增加。就此看:跑赢大势应是举手之劳,可跑赢大势仍是基金操盘手现在和未来的理想。从国内外基金经理的述职报告中都可见“跑赢大势”的艰难。
编辑公式首先要能读懂K线或者实时图。我们知道:趋势类公式只在牛市行情中期才有用,追涨的方法也是在此时才有用武之地。对于一些有明显缺点的股票,就不需公式帮助了。设立简单的预警即可。如:散户股的换手率方法。有些方法如:K线组合论明显不对(打开多日走势图就得知);周期分析至今还是猜想(只能事后演义);波浪理论简直可笑(但她的哲学基础至今无论能敌);价量关系已有了无可争议之结论(下载区),叠加分析可能是我国股市未来的热门投机分析方法(叠加分析类的公式用处不大,因为叠加很直观,无需公式的蛇足了)。目前公式适用最多的地方在均线类、反趋势类的实战技法中。公式排序的公式就是画蛇添鞋了。而公式大有可为的地方,在于它是套利对冲、操盘方案、程式交易的建筑材料,是猜想与理论实证工具。
大家迷信公式的同时不要忘记:

“股价在任何一点都可转向,没有一定要涨,或者一定要跌的道理”

公式要实现“参数的自动调整”,使用时机判断。参数自动调整问题:大家可效仿“济安线”的均线周期自动调整原理;时机类公式很少,有信趣的可来贴提出个人要求,我会考量满足你。
简单公式1.1 技术指标公式编辑器 技术指标公式即通常所说画线指标,此类公式的主要目的是通过对数据采取一定的运算,将输出结果直观的显现在分析图上,为投资者提供研判行情的基本依据。此类指标至少要有一条输出线,本系统允许最多6条的输出线。技术指标公式编辑器实现对技术图表分析中各类技术指标和自我定义的技术分析指标的编写,并且通过TDX的分析界面形成图表、曲线,以方便和寻找有意义的技术图形和技术特征。
1.2 条件选股公式编辑器 也就是通常意义上解释的智能选股。但我们的目的在于建立一个完全开放、自由的选股平台,可以通过对该平台的熟练使用,借助计算机的高速和准确的检索功能寻找满足您的理解的股票形态和技术特征,作到先知先觉,快人一步!并且提供相应的同样开放式的结果检测报告。
1.3 五彩K线公式编辑器 准确讲,该编辑器的功能是附属于条件选股功能之上的,我们可以通过该功能将满足条件的连续K线形态赋予颜色,区别了其它的K线。 条件选股公式与五彩K线公式的区别:条件选股公式和五彩K线公式都有且仅有一个输出,其目的都是为投资者提供买入或卖出点的指示,不同之处在于:条件选股公式仅对最近数据提示买入或卖出,而五彩K线公式则对输入的所有历史数据进行提示。另外,五彩K线公式的输出是在K线图上,通过各种颜色对提示数据进行标识,条件选股公式的输出是找出符合最近条件的所有股票。
1.4 交易系统公式编辑器 交易系统公式是通过设定买入和卖出点(有且仅有这两个输出),由计算机进行模拟操作。以此为依据,系统一方面可以进行五彩K线公式的功能,同时提示买入和卖出;另一方面可以通过模拟操作,对指标买卖的收益、指标的最佳参数及最佳指标等各情形进行测试。交易系统是在条件选股功能上的一次大的延伸,旨在建立一套完整的交易规则体系,通过该编辑器对各个相关的交易环节,包括买入的切入、卖出、止损以及整体的交易性能检验等等作出定量的规定,帮助投资者建立一套属于自己的买卖规则和理论。
TDX系统所有的分析方法,包括技术指标、条件选股、交易系统和五彩K线,均采用开放平台进行描述。也就是说,所有分析方法的算法对用户时开放的,任何人都可以对原算法进行修改,或增加自己的新算法。
快捷键:〖Ctrl〗+〖F〗在公式管理器中,用户可以对系统公式进行全面管理,包括新建公式,修改公式算法、引入、输出公式、设置组合条件等。公式管理器用树形结构显示系统中存在的所有分析方法,包括指标公式、条件选股公式、交易系统公式、五彩K线公式和组合条件。需要对哪一类公式进行处理,可以用鼠标点取将该类公式展开,直到找到需要的公式名称。 查找公式可以从公式组、全部、系统和自编四种列表方始中选择,公式组方式便于分类管理,全部方式便于有公式名称直接查找,系统方式便于系统内置常用指标的快速查找,而自编方式则便于查找自己编写的或从外部引入的公式。
公式管理器可管理四种类型的公式:指 标 公 式: 用于指标图形的绘制。条件选股公式:用于条件选股。交易系统公式:用于专家指示及测参、测指。五彩K线公式:用于K线模式指示。这四种公式相互独立,名称可以相同,但其内容和作用不同。每种类型的公式包括四种形式: 系统加密公式:用绿色图标和锁形符号显示,要进行密码确认 系统公式:用绿色图标显示,可进行删改 用户加密公式:用红色图标和锁形符号显示,要进行密码确认 用户公式:用红色图标显示,可进行删改指标公式附加买卖逻辑判断式,得到交易系统公式;指标公式附加选股条件逻辑判断式,得到条件选股公式。指标公式附加色彩逻辑判断,得到五彩K线公式。
调出公式管理器方法:
1.点击〖新建〗或〖修改〗按钮;
2.鼠标左键单击指标线、指标参数选中指标,再用右键单击,弹出的对话框中选中“修改指标公式”,系统弹出公式编辑器。公式编辑其中包含许多输入窗口和按钮,功能分别为:〖公式名称〗用于识别公式,最多可以有9个字符,该名称在每一类分析方法必须唯一,例如不能出现两个MA技术指标,但可以出现一个MA技术指标和一个MA条件选股指标。〖公式描述〗简单描述该指标的用途,可以输入任意字符。〖密码保护〗选中密码保护,表示将对该公式加密,加密密码输入到密码输入框中。对于已加密的公式,今后对它进行修改和查看必须先输入密码,在输出公式到文件时也需要密码。要去掉密码,点击“密码保护”,使它前面的√消失即可。〖画线方法〗这组单选按钮用于指定指标公式类型,紧密围绕股票价格变化的指标可定为主图叠加类型,叠加在主图上显示;否则定为副图指标,显示在副图上。(仅在编辑技术指标公式时出现)〖参数〗公式可以带有0-6个参数,使用参数可以方便地使用中需要修改得数值进行调整。每个参数需要设定参数名称、最小值、最大值和缺省值。〖坐标位置〗可指定在某些特殊位置画水平坐标线,例如对RSI,可以输入:0;20;50;系统将在这三个数值处绘制三条水平坐标线。缺省时为“自动”,即系统据实际情况定水平坐标线。(深红色线) (仅在编辑副图技术指标时出现)〖额外Y轴分界〗:在副图坐标中显示重要的数值分界线(白色线);〖测试公式〗检查公式的语法错误。〖引入指标公式〗以系统已有的某个指标公式为蓝本,新建自己的指标公式。〖插入函数〗显示选择函数对话框,帮助您在通达信函数集中寻找所需函数。当您对系统提供的标准函数还不熟时,这个功能可帮你节省时间。〖用法注释〗供用户输入指标算法、用法的解释,在使用公式时提示操作方法及注意事项。〖动态提示〗用户输入指标、算法或函数时,同步提示中文语意。〖参数精灵〗在使用分析工具时,很多时候用户都需要调整参数,但很多用户无法理解对参数调整的实际意义。使用参数精灵,可以将参数调整及参数意义放在同一段文字中,方便用户使用。用户在使用分析方法时,会在指标旁边显示参数精灵的内容。参数精灵的内容是由公式剪辑者输入的一段文字,该文字描述了参数的使用方法,并且可以将参数设置与文字混合编辑。
方法是用Param#N来代替参数即可。例如:公式中有两个参数M和N,需要描述当M日均线与N日均线金叉时买入,可以这样写参数精灵: Param#1日均线与Param#2日均线发生金叉,发出买入信号在实际使用该分析方法时,系统将显示: 5日均线与10日均线发生金叉,系统发出买入信号其中被包围在输入框中的5和10是参数,用户可以直接修改这些参数,而实际运算时将采用这些参数进行计算。使用参数精灵大大降低了公式的使用难度。
〖公式编辑窗〗公式编辑窗用于书写分析方法的算法,是公式编辑器的核心部分。用户可以将自己的算法用公式语法书写到编辑窗中,关于公式语法请参见附录。公式编辑器在使用上十分灵活,支持丰富的键盘操作和鼠标操作。
第2节 公式编写规则 所有的公式系统都是遵守统一的运算法则,统一的格式进行函数之间的计算,所以我们掌握了技术指标公式的基本原理,其他的公式也不会出脱其外。例如指标公式:KDJ,右键点击KDJ,选择“编辑公式”后打开公式算法编辑器,显示出KDJ指标公式的内容。参数名称:缺省值,最小值,最大值 N:9,1,10O M1:3,2,40 M2:3,2,40 RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100; K:SMA(RSV,M1,1); D:SMA(K,M2,1); J:3*K-2*D;该公式绘制K、D、J三条指标线。RSV行是一个中间语句,计算当期收盘价与N天内最低价之差除以N内最高价与最低价之差的比值,再乘以系数100。K线为RSV的M1天移动平均线,D线为线K的M2天移动平均线,J线为K线与J线的差值。
简单公式编辑第2节 公式编写规则
所有的公式系统都是遵守统一的运算法则,统一的格式进行函数之间的计算,所以我们掌握了技术指标公式的基本原理,其他的公式也不会出脱其外。例如指标公式:KDJ,右键点击KDJ,选择“编辑公式”后打开公式算法编辑器,显示出KDJ指标公式的内容。
参数名称:缺省值,最小值,最大值
N:9,1,10O
M1:3,2,40
M2:3,2,40

RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:SMA(RSV,M1,1);
D:SMA(K,M2,1);
J:3*K-2*D;
该公式绘制K、D、J三条指标线。RSV行是一个中间语句,计算当期收盘价与N天内最低价之差除以N内最高价与最低价之差的比值,再乘以系数100。K线为RSV的M1天移动平均线,D线为线K的M2天移动平均线,J线为K线与J线的差值。

指标数据引用:
经常地编制公式的过程当中,需要使用另外一个指标的值,如果按照通常的做法,重新编写过这个指标显得麻烦,因此有必要学习使用如何调用别的指标公式。
基本的格式为:“指标.指标线”(参数)
a) 指标和指标线之间用逗号分开,一个指标不—定只有一条指标线,所以有必要在指标后标注指标线的名称,但是如果缺失则表示引用最后一条指标线。
b) 参数在表达式的末尾,必须用括号括起来,参数之间用逗号分开,通过参数设置可以选择设定该指标的参数,如果参数缺失则表示使用该指标的默认参数设置。
c) 整个表达式用引号引在其中,除参数以外。例如:“MACD.DEA”(26,12,9)表示计算MACD指标的DEA指标线。计算参数为26、11、9, “MACD”(26,12,9)表示该指标的最后一条指标线,计算参数是26、12、9, “MACD”表示该指标的最后—条指标线并且使用公式的默认参数。

B 跨周期引用指标数据:
a) 引用大盘数据:引用大盘数据时使用下列函数: INDEXC/NDEXV,等等!
b) 引用个股数据:引用个数据时使用下列格式:“股票代码$数据”.在以上格式当中调用CLOSE,VOL,AMOUNT等等!例如“000002$VOL'表000002该股本周期的成交量。“999998$CLOSE"同样也可以表示为A股指数本周期的收盘价,此时的A股指数被视为一只个股。

C 其它股票数据引用:
使用以下的格式可以在当前的分析界面下引用大盘的数据或者其它个股的数据实现横向上的对比。
a) 引用大盘数据:引用大盘数据时使用下列函数: INDEXC/NDEXV,等等!
b) 引用个股数据:引用个数据时使用下列格式:“股票代码$数据”.在以上格式当中调用CLOSE,VOL,AMOUNT等等!例如“000002$VOL'表000002该股本周期的成交量。“999998$CLOSE”同样也可以表示为A股指数本周期的收盘价,此时的A股指数被视为一只个股。

A公式语句
所有的公式体由若干语句按照一定的格式组成,每个语句表示一个计算结果,根据各个语句的功能分为两大类语句,一类是赋值语句,一类是中间表达式。
B赋值语句:
在技术指标“B:AZ”和“c:B*0.618”就是分别两条指标线,语句间用分号隔开。该语句被称为赋值语句,在技术指标当中,赋值语句的计算结果将会被计算机执行并形成相应的图形。每个语句可以有一个名称,该名称写在语句的最前面,并用一个冒号将它与语句分隔开。例如:ST:MA(CLOSE,5);表示该语句求收盘价的五日均线,语句的名称为ST。在该语句后的语句中可以直接用ST来替代MA(CLOSE,5),例如:MA(ST, 5)表示对收盘价的五日均线再求五日平均。

C中间语句;
一个语句如果不需要显示,可以将它定义为中间语句,例如在上例当中的第一句“A:=X+Y;”,这样该语句就不会披系统辨认为是指标线了。中间语句用“:=”替代冒号,其它与一般语句完全一样。使用中间语句可以有效降低公式的书写难度,还可以将需要重复使用的语句定义成中间语句以减少计算量。每个公式最多可以分6个语句,中间公式数量没有限制,所有语句之间需要使用分号隔开。
D公式计算符
公式计算符将函数连接成为公式。计算分为算术计算符和逻辑计算符。
a)算术计算符
包括十、一、*、/,它们分别对计算符两边的数据进行加减乘除计算,这同一般意义上的算术计算没有差异。
b)逻辑计算符
包括>、<、<>、>=、<=、=、AND、OR八种,分别表示大于、小于、不等于、大于等于、小于等于、等于、逻辑与、逻辑或运算,如果条件成立计算结果就等于1,否则等于0。例如:3+4等于7,4>3就等于1。“逻辑与”表示两个条件都成立时结果才成立:“逻辑或”表示两个条件中只要有一个成立结果成立。例如:4>3ANDl2>=4的结果等于1,4>3 0R 3>12的结果等于1。
E 线形描述符
对于技术指标公式可以在语句加上线形描述符.用来表示如何画该语句描述的指标线。线形描述符包括以下7种。描述符写在语句后分号前,用逗号将它与语句分隔开,例如在上例当中加入一句线形描述符,c:B*0.618,COLORSTICK;该语句在被执行时,会在图中添加彩色柱线,该功能在编制MACD等指标的时候会显出它的用处。
a) COLORRED等三个线形描述符还可以自定义颜色,格式为COLOR+“BBGGRR”:BB、GG、RR表示蓝色、绿色和红色的分量,每种颜色的取值范围是00-FF,采用了16进制。例如:MA5:MA(CLOSE,5),COLOR00FFFF表示纯红色与纯绿色的混合色:COLOR808000表示淡蓝色和淡绿色的混合色。
b) LINETHlCK可以允许对线型的粗细进行白定义的描述,格式LINETHICK+(1-9)”;参数的取值范围在1—9之间,“LINETHICK1”表示最细的线,而“LINETHICK9”表示最粗的线;

2.4 关于无效数的问题
所谓无效数即指没有数据。在某些情况下,一些数据项可能取不到数据,这时返回值为无效数。例如,MA(CLOSE,500),其含义是该股票最近500天收盘价的均价,如果有些公司上市时间较短没有500天,则其值为无效数。反应在分析图上则该指标线不显示。在TDX分析系统中函数NODRAW代表无效数,可作为常数使用。
无效数与任何数作计算,其结果仍为无效数。例如:7*NODRAW得到的结果仍为NODRAW。
第3节 公式编写示例
? 公式示例
? 指标公式:均线通道
? 选股公式:均线通道
? 五彩K线公式:均线通道
? 交易系统公式:均线通道
? 颜色参数应用:MACDK
? 新增函数应用:HORCALC(X)
? 新增函数应用:BLOCKSETNUM(板块名称)

简单公式

这里举一些最简单的公式例子,有些只有一条语句且函数简单,较复杂的公式中函数复杂且语句较多。

收盘价线
这是最简单的公式:
CLOSE;

均线
计算N日内收盘价的算术平均值,它是最常用的指标之一,公式为:
MA(CLOSE,5);
其中的MA(X,N)表示X的N日平均。

涨幅
涨幅指今日收盘价相对于昨日收盘价的变动幅度,即(今日收盘价-昨日收盘价)/昨日收盘价*100%,  昨日收盘价的公式为:REF(CLOSE,1),因此涨幅的公式:
(CLOSE-REF(CLOSE,1))/REF(CLOSE,1);

换手率
换手率指当期的成交量占流通股本的比例。
公式:
VOL/CAPITAL;
VOL为当期成交量,CAPITAL为流通股本。

创新高
创新高指当日最高价是最近一段时间的最高价:
HIGH=HHV(HIGH,N);
其中的HIGH为当期最高价,HHV(X,N)是求N周期内X最高值。因此该公式的含义是当日最高价创N日新高时返回值为1,否则为0。

横盘整理
横盘整理指最近一段时期价格在一定幅度之内摆动:
(HHV(CLOSE,10)-LLV(CLOSE,10))/CLOSE<0.05;
其中的LLV(X,N)是求N周期内X最低值。因此该公式表示10日收盘价振幅振幅在5%以内。

区间统计
例如,要取得2002年2月1日到2002年12月30日间的最低价。思考一下,一段时间的最低价必然是该段时间内每个分析周期的最低价中最小的那个。所以我们要引用的数据是该段时间各分析周期的最低价,而不需要用到开盘价、收盘价或最高价;还要将不需要的数据,即区间外的数据设为0。语句为:
LL:=IF(YEAR=2002 AND MONTH>=2 AND MONTH<=12,LOW,0);
该语句用一个条件函数来判断时间是否处于规定区间,若是则返回最低价,否则返回0。
我们再用LLV函数,就可求得该段时间最低的最低价:
LLV(LL,N);
N为日期参数,N为0,则上式表示:上市以来的最低价。

技术指标公式
技术指标公式用于绘制技术指标线。以KDJ指标为例,右键点击KDJ,选择“编辑公式”后打开公式算法编辑器,显示出KDJ指标公式的内容。
参数名称: 最小值 最大值 缺省值
N: 1 10O 9
M1: 2 40 3
M2: 2 40 3
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:SMA(RSV,M1,1);
D:SMA(K,M2,1);
J:3*K-2*D
该公式绘制K、D、J两条指标线。
RSV行是一个中间语句,计算当期收盘价与N天内最低价之差除以N内最高价与最低价之差的比值,再乘以系数100。
K线为RSV的M1天移动平均线;
D线为线K的M2天移动平均线;
J线为K线与J线的差值。
条件选股公式条件选股公式
条件选股用于选出满足条件的股票,条件选股公式用于显示条件是否满足的语句是一个逻辑表达式,条件满足,表达式的返回值为“1”,表示选中该股,条件不满足,返回值为为“0”,表示未选中。条件选股公式的其他公式必须是中间公式,而且要在逻辑表达式之前。以KDJ指标买入条件选股为例,右键点击“KDJ指标买入条件选股”,选择“编辑公式”后打开公式算法编辑器,显示出公式的内容。
用KDJ随机指标作为买入条件是当J向上穿越0坐标线的时候
公式写法为:
参数名称:最小值 最大值 缺省值
N: 1 10O 9
M1: 2 40 3
M2: 2 40 3
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:SMA(RSV,M1,1);
D:SMA(K,M2,1);
J:3*K-2*D;
CROSS(J,0);
如果直接引用指标公式,KDJ条件选股公式可以简写为:
CROSS("KDJ.J"(N,M1,M2),0);

3.2 指标公式:均线通道
新建公式“均线通道”(JXTD)
1.使用快捷键Ctrl+F打开“公式管理器”。

2.点击“新建”按钮,打开“公式编辑器”

3.填写公式项
“公式名称”---JXTD,
“公式描述”---“均线通道”
参数 (最小值)(最大值)(缺省值)
#N: 1 100 26
--------------------------------------------------
VAR1:=MA(CLOSE,N);{对“VAR1”赋值}
VAR2:=MA(CLOSE,2*N);{对“VAR2”赋值}
VAR3:=MA(CLOSE,3*N);{对“VAR3”赋值}
VAR4:=MA(CLOSE,4*N);{对“VAR4”赋值}
VAR5:=MA((VAR1+VAR2+VAR3+VAR4)/4,5);{一条多条均线的平均线}
上轨:VAR5*1.08;{在均线“VAR5”上加上8%的幅度变成“上轨”}
下轨:VAR5*0.92; {在均线“VAR5”上减去8%的幅度变成“下轨”}
----------------------------------------------------
4.指标类型:选“路径型”,还有大势型、超买超卖型、趋势型、能量型等如图

5.画线方法:副图、主图叠加、副图叠加线、副图叠加美国线四种;选中“主图叠加型”,副图是K线图下面的区域;
6.密码保护:010101
7.参数设置:#N:最小值为1,最大值为100,缺省值(默认)为26;
8.坐标线位置:在非“主图叠加”中,此编辑框处可写状态;输出线为副图中深红色横线显示,是副图坐标线;
9.额外Y轴分界:是指标敏感数值输出线,在副图中显示为白色;
10.引入指标公式:在引入原公式的基础上进行编辑;
11.插入函数:左上为函数类别,右上为函数表,下区为函数解释区及用法举例;

12.公式编辑区:
〖{ }〗是解释,不输出,为了提示自己和别人,便于看懂公式;
〖:=〗赋值符,意为“相当于”;
〖:〗输出符,它前面的名称为输出名称,可以在副图中看到,它后面的为公式定义;
〖;〗分段符,表示一段完成;
〖,〗分节符;
〖()〗括号中为公式体。
13.测试公式:测试通过则自动保存;测试不能通过,则在翻译区提示错误所在。
14.用法注释:自编公式使用说明。
15.在K线图上,直接敲字母键“JXTD”调出自编的公式“均线通道”,查看结果;
16.修改公式:左键选中公式线后,点击右键,在弹出的对话框中,选中“修改指标”项,直接调出《公式编辑器》修改公式。如果左键选指标线不便,直接用右键选参数数值,也可调出公式编辑器。

17.鼠标动态提示:将鼠标放在函数上,等一会系统自动出现提示框,方便函数学习和应用,如图:

3.3 选股公式:均线通道

改公式“均线通道”(JXTD)为选股公式“均线通道”
1. 〖Ctrl〗+〖F〗打开“公式管理器”;
2. 点击“条件选股公式”选项;
3. 点击“新建”按钮,打开“条件选股公式编辑器”;
4. 点击“引入指标公式”按钮,选最后一项“均线通道”,确定;

5.修改输出:公式输出项改为赋值项;即将〖:〗符改为〖:=〗符;
6.新建输出项:选股:CLOSE<下轨;{选出收盘价小于下轨的股票};如图

7.测试公式通过;
8. 〖Ctrl〗+〖T〗打开条件选股公式“均线通道”,进入公式选股操作程序;

3.4 五彩K线公式:均线通道
改公式“均线通道”(JXTD)为五彩K线公式“均线通道”
1. 〖Ctrl〗+〖F〗打开“公式管理器”;
2. 点击“五彩K线公式”选项;
3. 点击“新建”按钮,打开“K线指示公式编辑器”;
4. 点击“引入指标公式”按钮,选“均线通道”确定;

五彩K线公式
公式名:JXTD
公式描述:均线通道
参数 (最小值)(最大值)(缺省值)
#N: 1 100 26
--------------------------------------------------
VAR1:=MA(CLOSE,N);{对“VAR1”赋值}
VAR2:=MA(CLOSE,2*N);{对“VAR2”赋值}
VAR3:=MA(CLOSE,3*N);{对“VAR3”赋值}
VAR4:=MA(CLOSE,4*N);{对“VAR4”赋值}
VAR5:=MA((VAR1+VAR2+VAR3+VAR4)/4,5);{一条多条均线的平均线}
上轨:=VAR5*1.08;{在均线“VAR5”上加上8%的幅度变成“上轨”}
下轨:=VAR5*0.92; {在均线“VAR5”上减去8%的幅度变成“下轨”}
CLOSE<下轨,COLORRED; {小于下轨提示买入红色}
CLOSE>上轨,COLORYELLOW; {高于上轨提示卖出黄色}
HIGH>上轨*1.06,COLORBLUE;{高于上轨6%提示清仓蓝色}
LOW<下轨*0.94, COLORMAGENTA;{低于下轨6%提示加仓洋红色}
--------------------------------------------------
5.测试通过,退出;
6.〖Ctrl〗+〖K〗,打开“五彩K线指示”---“均线通道”;
7.查看效果,不满意就修改参数一直到满意为止;
3.5 交易系统公式
改公式“均线通道”(JXTD)为交易系统公式“均线通道”
1. 〖Ctrl〗+〖F〗打开“公式管理器”;
2. 点击“交易系统公式”选项;
3. 点击“新建”按钮,打开“交易系统公式编辑器”;
4. 点击“引入指标公式”按钮,选“均线通道”确定;
公式名:JXTD
公式描述:均线通道
参数 (最小值)(最大值)(缺省值)
#N: 1 100 26
--------------------------------------------------
VAR1:=MA(CLOSE,N);{对“VAR1”赋值}
VAR2:=MA(CLOSE,2*N);{对“VAR2”赋值}
VAR3:=MA(CLOSE,3*N);{对“VAR3”赋值}
VAR4:=MA(CLOSE,4*N);{对“VAR4”赋值}
VAR5:=MA((VAR1+VAR2+VAR3+VAR4)/4,5);{一条多条均线的平均线}
上轨:=VAR5*1.08;{在均线“VAR5”上加上8%的幅度变成“上轨”}
下轨:=VAR5*0.92; {在均线“VAR5”上减去8%的幅度变成“下轨”}
{多头买入} ENTERLONG:CLOSE<下轨;
{多头卖出} EXITLONG:CLOSE>上轨;
---------------------------------------------------

5.测试通过,退出;
6.〖Ctrl〗+〖E〗,打开“五彩K线指示”---“均线通道”;
7.查看效果,不满意就修改参数一直到满意为止;

8.删除指示:快捷键〖Ctrl〗+〖H〗;鼠标左键选中指示图标,按〖Delete〗,或者点击鼠标右键,在弹出的菜单中选“删除交易系统指示”。

3.6 颜色参数应用:“MACD”K线
公式名称:MACDK
简称:“MACD”K线
----------------------------
DIF:EMA(CLOSE,SHORT)-EMA(CLOSE,LONG);
DEA:EMA(DIF,MID);
MACD:(DIF-DEA)*2,COLORSTICK;
D1:=EMA(C,3)-EMA(C,8);
D2:=EMA(O,3)-EMA(O,8);
D3:=EMA(H,3)-EMA(H,8);
D4:=EMA(L,3)-EMA(L,8);
DRAWICON(CROSS(D1,DIF) AND DIF<0 ,D4-0.1,10);
DRAWICON(cross(diff,d1) and diff>0.1 ,d3+0.1,2);
STICKLINE(D1>=D2,D1,D2,8,0),COLOR0055AA;
STICKLINE(D1<=D2,D1,D2,8,0),COLOR006600;
STICKLINE(D1>=D2,D1,D2,5,0),COLOR0077CC;
STICKLINE(D1>=D2,D1,D2,3,0),COLOR0099DD;
STICKLINE(D1>=D2,D3,D4,0,0),COLOR00BBFF;
STICKLINE(D1<=D2,D1,D2,5,0),COLOR009900;
STICKLINE(D1<=D2,D1,D2,3,0),COLOR00BB00;
STICKLINE(D1<=D2,D3,D4,0,0),COLOR00EE00;
------------------------------

3.7 新增函数应用HORCALC(X)
函数: HORCALC(X)
说明: 数据项:100-HIGH,101-OPEN,102-LOW,103-CLOSE,104-VOL,105-涨幅
计算方式:0-累加,1-排名次
权重:0-总股本,1-流通股本,2-等同权重,3-流通市值
用法: HORCALC(板块名称,数据项,计算方式,权重)
例如: HORCALC('自选股',103,0,1);以自选股板块股票的总股本为权重,以收盘价为数源进行累加。

公式名称:zdkx
公式描述:自定指数K线
参数:(最小值)(最大值)(缺省值)
#n: 1 100 10
---------------
高:=HORCALC('湖北板块',100,0,1);
开:=HORCALC('湖北板块',101,0,1);
低:=HORCALC('湖北板块',102,0,1);
收:=HORCALC('湖北板块',103,0,1);
自定K线: DRAWKLINE(高,开,低,收);
MA(自定K线,N);
---------------

公式说明:
1.用于制作自定义指数、自设板块指数K线。
2.先制作自定义板块,“Ctrl+z”,填写好板块名称和简称(数字);
3.“板块名称”须用单引号,如'自选股'、'庄股';
4.起始位为1000点(下载到本地数据);
5.板块内不要含有太多的股票数量,以免影响速度;

3.8 新增函数应用BLOCKSETNUM(板块名称)
函数: BLOCKSETNUM(板块名称)
说明: 统计板块中股票数量
用法: BLOCKSETNUM(板块名称)
注意:板块名称要用单引号
例如: BLOCKSETNUM('ST板块'),返回“ST板块”数量。

公式名称:STPM
公式描述:个股在st板块内排名
--------------
板块股数量:BLOCKSETNUM('ST板块'),NODRAW;
ST涨幅排名:HORCALC('ST板块',105,1,2);

说明:
NODRAW是不输出线型只输出数值命令,用于多指标不兼容坐标;
公式证伪专业操盘手的核心机密法则
法则一:买股票前先进行大势研判
   1、大盘是否处于上升周期的初期——是——选股买入。
   2、宏观经济政策、舆论导向有利于那一个板块,该板块的代表性股票是哪几个,成交量是否明显大于其它板块。确定5-10个目标个股。
   3、收集目标个股的全部资料,包括公司地域、流通盘、经营动向、年报、中报,股东大会(董事会)公告、市场评论以及其它相关报道。剔除流通盘太大,股性呆滞或经营中出现重大问题暂时又无重组希望的品种。
   法则二:中线地量法则
   1、选择(10,20,30)MA经六个月稳定向上之个股,其间大盘下跌均表现抗跌,一般只短暂跌破30MA。
   2、OBV稳定向上不断创出新高。
   3、在大盘见底时地量出现,以3000万流通盘日成交10万股为标准。
   4、在地量出现当日收盘前10分钟逢低分批介入。
   5、短线以5%-10%为获利出局点。
   6、中线以50%为出货点。
   7、以10MA为止损点。
   法则三:短线天量法则
   1、选择近日底部放出天量之个股,日换手率连续大于5%-10%,跟踪观察。
   2、(5,10,20)MA出现多头排列。
   3、60分钟MACD高位死叉后缩量回调,15分钟OBV稳定上升,股价在20MA之上走稳。
   4、在60分钟MACD再度金叉的第二个小时逢低分批进场。
   5、短线获利5%以上逢急拉派发。
   6、一旦大盘突变立即保本出局,以利再战。
   法则四:强势新股法则
   1、选择基本面良好、具成长性、流通盘6000万以下新股观察。
   2、上市首日换手70%以上。或当日大盘暴跌,次日跌势减缓立即收较大阳线收复首日阴线三分之二以上。
   3、创新高买入或选择天量法则买点介入。
   4、获利5%-10%出局。
   5、止损为设为保本价。

法则五:成交量法则
   1、成交量有助于研判趋势何时反转:高位放量长阴线是顶部的迹象,而极度萎缩的成交量说明抛压已经消失,往往是底部的信号。口诀:价稳量缩才是底。
   2、个股成交量持续超过5%,是主力活跃其中的明显标志。短线成交量大,股价具有良好弹性,可寻求短线交易机会。
   3、个股经放量拉升、横盘整理后无量上升,是主力筹码高度集中,控盘拉升的标志,此时成交极其稀少,是中线买入良机。
   4、如遇突发性高位巨量长阴线,情况不明,要立即出局,以防重大利空导致崩溃性下跌。例如,0508琼民源,停牌前一天放量下跌,次日遭停牌,长达三年。
   法则六:不买下降通道的股票
   1、猜测下降通道股票的底部是危险的,因为他可能根本没有底。
   2、存在的就是合理的,下跌的股票一定有下跌的理由,不要去碰它,尽管可能有很多人觉得它已经太便宜了。
   法则七:要敢于买入创新高的股票
   1、95%的人不敢买创新高的股票,这是他们总抓不住大黑马的原因,龙头股然是率先创出新高的品种。
   2、当某只股票创新高时,其中必含重大意义──该股票一定有一些事情发生了改变,不论有多少人宣称,基本面并未改变,而且也没有理由涨到如此高位。这种故事几乎每天都在上演,人们还是无法克服恐惧。
   法则八:勇于止损
   1、首先要明白没有谁不曾亏钱,没有睡是百发百中,因为要知道市场上有太多不确定的因素。
   2、一旦出现与预想不同的情况,宁可错失一次机会也要果断止损出局,保持资金的自由,耐心等待下一个交易机会。
   3、不设止损不买股。
   法则九:分批买入一次买出
   1、确定目标股票后结合盘口走势,试探性买入,趋势确立后再逐渐加码,不可一次性满仓买入,避免因分析不全面导致太大损失。
   2、到达目标位则一次性了结,不可拖泥带水,贻误下一次交易机会。
kdj本质kdj 祥解 kdj 公式体如下:
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
{(收盘价-N日内最低价的最低值)/(N日内最高价的最高值-N日内最低价的最低值)*100}
K:SMA(RSV,M1,1);{RSV的M1日[1日权重]累积平均}
D:SMA(K,M2,1);{K的M2日[1日权重]累积平均}
J:3*K-2*D;{3*K-2*D}
解释:
1.第一行代码:现价减区间最低价,然后除以9天区间涨跌幅,得出现价在区间涨跌幅中间的比值%;就是说现在价格处在9天最高价与最低价的什么位置%;可见最小是0,最大是100;
2.第二行代码:k是RSV的3日均线;
3.第三行代码:D是k 的3日均线;
4.第四行代码:J 是K、D两条均线的差值;为了看清公式的含义,二三四行代码是第一行代码的加工,我们可以直接删除二三四行代码,留下第一行并输出;
操作如下:新建公式kdjj RSV: (CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
看到的是现价处在9天涨跌幅中的比例%;为了更清楚看清本质,将公式类型改为主图叠加型;结果很直观看出kdj公式的含义,
操作如下:新建公式:kdjjj 画线类型 :主图叠加型 RSV: LLV(LOW,N); RSS:HHV(HIGH,N); [说明]:kdj本质是区间高低价;
凡是k现与指标线接触的日期 就是rsv值为0或者100的日期,也是kdj的k值最高或最低的日期;
反思:筹码论反思:筹码论-量堆积图
量大量小表明市场人士争议的多少,多空战争规模的大小。

以量堆集图预测股价的理论,远不如轮廓理论有用。还没找到量堆积图有什么用的证据之前,我们不能向股民作出推介和傻论!!那位大虾提点证据我看看!
股价的运动与量的相关性是有,但是,仅限于价量比小于量价比的区间:JLB<LJB,其它时候,看不到价量相关性。你能用1/8的相关区间来推理7/8的非相关区间的价量关系吗?
技术分析派的古老理念:“股市价格以外的因素可以不考虑”。关于筹码其实质就是成交量的纵向堆积。
如:成本均线(mcst)
成本均线: dma(amo/vol,hsl/100);
你能看出过一二三吗?
神仙能看出什么道道?
还是软件商人的“不误证业”造成的?
逆市选股法逆市选股法 (一)

逆市缩量平台

  众所周知,大盘下跌中能逆势企稳甚至上升的个股,要么是主力仍驻其中,要么是主力趁

机吸货。这两个基本的判断得出一个结论:主力在场。故此,关注逆市股可谓是漫漫熊途中寻

求避风港的最佳策略。这其实正是股谚“跌市重质““该跌不跌就看涨“的精华所在。本法正

是从此原理出发,通过对逆市形态的捕捉,进而争取在与主力博弈中处于主动位置而最终获

利。

  就形态而言,我们要介绍的第一个形态是在大盘下跌中,庄股悄然构筑出的逆市缩量平

台。正因为其安全性较高而成为我们的首要关注。其特征主要有:

  一、在大跌市仍能缩量企稳构筑平台,逆市时间越长潜力越大。其中特别要强调平台要缩

量,这是该形态中最关键的一点。因为在大盘下跌、压力区抛压等多重压力之下该股仍能够企

稳,并且缩量,这已经很清楚地说明了两点:一是有主力在场,所以不跟随大盘下跌;二是主力

一定达到至少相对控盘程度,才能在缩量的情况下保持股价不跌。同时,主力既然控盘,其伺机

拉升的意愿势必强烈,相对而言,投资者处于主动地位。

  二、选择价位在主力成本区或相对底部的股票较安全。对投资者而言,可以首先淘汰掉主

力高度控盘且股价在相对高位的逆市股票,除此之外介入剩下的逆市股风险不是特别大,这在

调整市中有利于自我保护。其中的主力成本区一般可用成交密集区进行替代分析。

  三、此类股一旦在大盘企稳时开始突破,其拉升时往往逐步连续性放量。因为此前的平台

缩量其实是成交量的累积阶段,从成交量的转换原理看,后面阶段就有个成交量的释放期,这

恰好与拉升期需要放量的要求相辅相成。另外,正由于成交量集中持续地放大,造成股价运行

的惯性较大,像刹车后失去动力但车仍会继续前行一样,股价在成交量缩小时仍会惯性上行,

形成成交量的顶背弛,但这时候往往也就是股价将见顶的信号,应择机抛出。

  四、在操作策略上,可等待出现连续放量突破时及时买入。这时虽然不是介入的最低点,

但往往是最安全点。
逆市选股法(二)

逆市温和放量

一、形态特征

  此类逆市股的形态特征主要有:

  1、逆市小幅拉升,呈现轨道型,且累计升幅不大,在10%左右;

  2、成交量温和放大,但换手率不大,一般最高在5%左右;

  3、此类逆市股往往是短线品种,在突破时一般放大成交量,连续拉长阳。

二、形成原因

  这类逆市股形成的原因主要有:

  1、主力逆市拉升收集筹码。在调整市中,由于市场恐慌因素往往造成散户非理智地抛售

股票,这种恐慌气氛为主力收集筹码提供了较好时机。而主力积极收集筹码势必会造成成交量

的温和放大。当然,成交量总体水平也不能过于显眼,以免引起市场过早关注而暴露行踪。

  2、主力缩量洗盘完毕,刚刚准备进入拉升,但因看盘失误或者其他不可测因素大盘走坏,

造成拉升计划短期受阻,在资金实力承受范围内,主力只能暂时护盘。另外,由于其放量启动趋

势基本确立,故此为维持市场人气,短期主力仍需要制造成交活跃以维持趋势。

  此类逆市股一旦正式启动,一般以连续拉升为主。因为主力底部护盘得力,逆市放量表现

又说明其信心充足,故此筹码到位后一旦大盘出现企稳反弹迹象,其必将充分利用市场时机拉

升。在走势上往往表现为:启动(初级阶段段)多以中阳上升制造突破,且少回调、少反复;否

则,一旦出现滞涨则很可能是主力筹码运作出问题,投资者应遵循“该涨不涨------看跌“操

作策略。

三、操作策略

  操作上,投资者可选择以下时机介入:

  1、在结束缩量平台调整后,初步温和放量拉升即碰到大盘打压、但又能盘稳者,可介入。

此类个股往往也是大盘反弹中的龙头板块或个股所在。特别在短期大盘暴跌当日,选择经过平

台缩量后再放量开始突破拉升的进攻型。

  2、温和放量拉升者一旦出现中阳以上大成交量,并突破盘升轨道,可大胆介入,其强烈的

惯性作用往往会带来短线的丰厚利润。

逆市选股法(三)

上升三角形

一、基本情况

  上升三角形是所有整理形态中最强势的中继技术形态。若在下跌市中出现此图形,强势图

形与逆市法的结合往往是投资者的最佳选择。

  从形态结构看,上升三角形的高位区基本在同一水平区域,股价反复地冲击这一压力区,

这表明市场积极攻击该区域以消化压力,主力收集筹码做多意愿极为强烈。另一方面,在形态

的多次回调中,最明显的特征是低位逐步上升,究其原因,源于投资者对其看好而在回调中积

极吸纳,同时也反映出主力惜售而不愿打压过深以免丢失筹码的心理。由此可见,上升三角形

具备进攻时积极、回守时惜售的市场特征,自然成为最强势的上升中途整理形态。

  值得注意的是,若该形态是在大盘的下跌过程中逐步形成的,根据逆市选股本质在于发掘

主力动向的出发点,由于该股有主力在场而值得关注,并且由于主力做多意愿相当强烈,对投

资者而言是首选品种。有鉴于此,逆市上升三角形堪称为逆市选股法

二、特征分析

  由于该形态反映了主力逆市收集的迫切心态,其在成交变化上的特征尤为关键:

  1、形态形成一般以逆市温和放量上升为开端,这是主力初步入场阶段。由于需要激活股

性,往往造成成交量快速放大,一般也是该形态中最大成交量的阶段。

  2、之后在多次上升冲击压力位及回调洗盘时,呈现出良好的价升量增、价跌量缩的价量

配合现象,反映筹码良性分配。

  3、形态末段明显缩量,震幅减小。这是形态成交特征中最关键的特征。此时说明主力基

本控制盘口,筹码锁定良好。

  4、突破拉升阶段强调持续放大交易量。由于上升三角形拉升往往是连续大幅飙升,投资

者甚至可以在突破放量信号出现后追高介入。

  5、天量非天价。一般拉升期出现价量背驰才是顶部出现的信号。

三、注意事项

  1、由于该形态本身的强势特征,加之缩量逆市对投资者而言是最安全形态,故该形态构筑

过程中放量与否不太重要,缩量有时反而说明控盘程度高。

  2、此形态主力做多意愿强烈,对筹码锁定严格,构筑过程中价量配合必须良好。

  3、形态构筑中不必每个阶段都逆市,关键在于整体形态能否在逆市中完全形成。有时在

下跌末段保持随市打压(但总体形态仍维持完好)的走势,说明主力踩准市场节奏运作筹码,后

市潜力更大。
支撑与阻力:

初学股票寻找压力、支撑是一大难题,选取合适的压力位与支撑位是一项基本功,它是短线选股的基础

1.支撑与阻力:筹码集中已形成支撑位、阻力位。原理是:价格回到交易集中的区间速度会减慢。
2“横有多长,竖有多高”的空间支撑、压力柱
3.“整数支撑与压力” “趋势支撑与压力” “30%”支撑与压力(空间压力与支撑) 麦克压力与支撑(指标压力与支撑) 箱体压力于支撑(空间压力支撑)
4.指标压力与支撑:WR,BOLL,MA,RSI
5.心理压力与支撑位:市场人士获得共识到“心理关口”。波动习惯的压力与支撑 “天无三日晴”
6.平台压力与支撑“平台支撑、压力”
7.K线形态压力支撑 :底部支撑、W底、双底、三角形底;平台支撑位;
技术分析方法的分类

  在价、量历史资料基础上进行的统计、数学计算、绘制图表方法是技术分析方法的主要手段。从这个意义上讲,技术分析方法可以有多种。一般说来,可以将技术分析方法分为如下五类:指标类、切线类、形态类、K线类、波浪类。
 
   (1)指标类。
   指标类要考虑市场行为的各个方面,建立一个数学模型,给出数学上的计算公式,得到一个体现股票市场的某个方面内在实质的数字。这个数字叫指标值,指标值的具体数值和相互间关系,直接反映股市所处的状态,为我们的操作行为提供指导方向。指标反映的东西大多无法从行情报表中直接看到。

  (2)切线类。
   切线类是按一定方法和原则在由股票价格的数据所绘制的图表中画出一些直线,然后根据这些直线的情况推测股票价格的未来趋势。这些直线就叫切线。切线的作用主要是起支撑和压力的作用。支撑线和压力线的往后延伸位置对价格趋势起一定的制约作用。一般说来,股票价格从下向上抬升的过程中,一触及压力线,甚至没有触及压力线,就会调头向下;同样,股价下跌过程中,在支撑线附近就会向上。另外,如果触及切线没有转向,而是继续向上或向下,这就叫突破。突破之后,这条切线仍然有实际作用,只是名称和作用变了,原来的支撑线变成了压力线,原来的压力线变成了支撑线。

  (3)形态类。
   形态类是根据价格图表中过去一段时间走过的轨迹形态预测股票价格未来趋势的方法。技术分析的第一条假设告诉我们,市场行为包括一切信息。价格走过的形态是市场行为的重要部分,是股票市场对各种信息作用之后的具体表现,用价格图的轨迹或者说是形态来推测股票价格的将来是很有道理的。从价格轨迹的形态中我们可以推测出股票市场处在一个什么样的大环境之中,由此对我们今后的行为给予一定的指导。著名的形态有M头、W底、头肩顶(底)等十几种。

  (4)K线类。
K线类的研究手法是侧重若干天K线的组合情况,推测股票市场多空双方力量的对比,进而判断股票市场多空双方谁占优势,是暂时的,还是决定性的。K线图是进行各种技术分析的最重要的图表。

  (5)波浪类。
   波浪理论起源于1978年美国人查尔斯?J?柯林斯发表的专著《波浪理论》。

  波浪理论是由美国人艾略特于1934年建立的一套有关股票价格波动和投资技术的理论。

  艾略特最初发明波浪理论是受到股价上涨下跌现象不断重复的启发,力图找出其上升和下降的规律。社会经济的大环境有一个经济周期,股价的上涨和下跌也应该遵循这一周期发展的规律。不过股价波动的周期规律同经济发展的循环周期是不一样的,要复杂得多。

  艾略特最初的波浪理论是以周期为基础的。他把周期分成时间长短不同的各种周期,并指出,在一个大周期之中可能存在一些小周期,而小的周期又可以再细分成更小的周期。每个周期无论时间长短,都是以一种模式进行。这个模式就是一个周期由8个过程组成,即每个周期都是由上升(或下降)的5个过程和下降(或上升)的3个过程组成。这8个过程完结以后,我们才能说这个周期已经结束,将进入另一个周期。新的周期仍然遵循上述的模式。以上是艾略特波浪理论的最核心的内容,也是艾略特作为波浪理论奠基人所作出的最为突出的贡献。

  艾略特波浪理论中的大部分理论是与道氏理论相吻合的。不过艾略特不仅找到了这些移动,而且还找到了这些移动发生的时间和位置,这是波浪理论较之于道氏理论更为优越的地方。道氏理论必须等到新的趋势确立以后才能发出买卖行动的信号,波浪理论可以明确地知道目前是处在上升(或下降)的尽头,或是处在上升(或下降)的中途,可以更明确地指导操作。

(6).广量指标
上涨下跌家数的统计分析。
抛物线转向操作系统(SAR)[教学]抛物线转向操作系统(SAR)
经常面临这样一个严峻的课题,股指(股价)振幅惊人,究竟何时持股,何时持币?价格和时间并重的分析工具SAR将是一个好帮手。 

抛物线转向系统不仅利用价位变动的动能,而且运用了时间变动性质来调整价位上设定的停损位置。SAR之递减或递增与实际价格之升跌幅度及时间长短有密切关系,可适应不同形态股价之波动特性。

SAR的实质就是多空立场的转变过程。当股价在停损点之上,我们将手中的股票保留,也就是我们所持的态度是看多,是多方。但股价跌破停损点之后,我们的行动是将手中股票抛出,也就是说我们所持的态度是看空,是空方。由多方变成空方完全是由股价是破停损点还是不破停损点而定。停损点成了多空转变的分界线。这也是SAR被成为停损转向的指标的原因。

第一,随着股价的上升每一天的停损点也应该相应地抬高,每天都根据情况的不同,计算出一个新的停损点。

第二,停损点被跌破之后,股价应该继续下跌。SAR就是帮助我们发现趋势转向,并且利用趋势获利的技术分析工具,它能帮助我们更好的把握好波段行情。

SAR的操作原则由于非常简单,故深受市场的青睐。买卖的进场实际是在价位穿过SAR时,也就是向下跌破SAR便卖出,向上越过SAR就买进。就拿1995年初上市的“西藏明珠”来说,短线客兢兢业业,只不过喝了点汤,而聪明人则依据宝塔线作小波段(6元显示明显买进信号,13元显示卖出信号),令人羡慕不已。

实证案例:96.7.24和96.8.12沪市构筑了典型的894点“双尊头”。联想到1995年的793点“双尊头”所形成的强大杀伤力,许多人士认为894就是沪市1996年的“顶”了。在这种思路灌输下,股指从894点直泻至750区域;正当市场不知所措时,96.9.20的抛物线转向操作系统却强调转折点并发出了买进信号,并一直维持至96.12的1071点,有力地驳斥了894点的“顶部论”,为“趋势理论”作出贡献。

SAR操作要诀(推论):经常交替出现讯号,说明大盘正处于盘局中,换句话说,可以大胆低吸高抛;一旦出现陡峭的上升(下跌)趋势,可一路持有(立即止损)。

实证案例:“渤海化工”上市首日以3.12元开盘,其后一路上冲,最高曾至8.30元作为带有H股的新股炒,市场定位有不确定因素,但SAR明确显示;从3.12~6.8元,SAR一路托住股价呈60度上升,是多实控制局面的持有信号。同理,95.10.13“渤海化工”的收盘价为6.75元,似乎还看出危险,但SAR已发出明显的空头转向信号,其标志的45度下,表明空头已牢牢控制局面,不根据SAR的指示而急于补仓,显然是不理智的。结果,这一跌势直至3.80元,SAR才开始发出多头向上信号。

实践证明:

第一,长期使用SAR指标可以输小赚大,不太可能一次就惨遭套牢。

第二,SAR是所有指标中买卖较为明确的,易于配合操作策略的指标,尤其适合强势股,故把它比做明镜高悬并不为过。

股价突破了SAR就是行动的信号。向下突破卖出,向上突破买入,这是所有技术指标中叙述起来最为简单的之一。不过,在实际应用时,应该注意以下几点。

1. 不一定非要到了股价突破了SAR才采取行动,可以提前。

2. 应用SAR最为重要的是明确当前是处于什么大环境。是上升还是下降,在股价为盘整局面时,SAR是不能使用的。

3. SAR是选势的指标,在具体选点时,配合摆数指标使用,就能买卖个更好的价钱。
布林指标参数设置布林指标的参数设置

一般的技术分析软件往往把指标参数默认值设为20。应该说以20为参数所设定而成的BOLL指标,在多数情况下,可以兼顾大多数股票价格的走势,具有"万金油"的作用。但特点不突出,对于价格趋势的运行不能发出最为准确的信号,而笔者通过实战发现,参数25却是一个理想的选择。

参数25无论对于指数走势还是股票价格走势都非常适合,尤其是在一些大的波动过程中,以参数25所设置而成的日K线BOLL指标能够为我们提供重要见顶或见底的信号。我们先来看一下上证综指的情况,2000年11月23日指数上冲到2126点的最高点并形成小幅冲高回落之后,开始进入阶段性的横盘整理,此时以参数25设置而成的BOLL指标波带开口收窄。在2001年1月初,指数开始重新出现上升行情,与此相应的是BOLL指标并未出现开口放大。

尽管指数连续两次创出了2132点的历史新高,但根据指标背离的原则,应当认为大盘创出新高是无力的,也是无效的。非常值得注意的是,当今年1月11日大盘再次创出2132点的新高时,走势正是受到了BOLL指标MB线的阻力,并迫使指数出现了下跌,同时指标开口出现放大,阶段性的下跌行情正式确立。而在2001年2月22日,指标在下跌到1893点后出现了止跌企稳,实际上从BOLL指标的角度来看,指数正是受到了其下轨DOWN线的支撑,从而得以出现止跌回升。

接下来再看一下凤凰股份(600679)的例子:该股是2001年涌现出的一只大牛股,这只股票行情爆发的时间是在2000年12月。当行情爆发时,原本极窄的BOLL指标波带开口突然明显放大,此时虽然股价形成了强力走高,指标出现了一定的滞后性,但在此后BOLL指标的开口继续放大,验证了价格运行趋势上升的可靠性(该股股价在形成第一波冲高之后略有回落,但指标开口并未缩小)。而在7月13日,凤凰股份股价形成明显的冲高回落,股价所受到的压制正是来自已经形成回落的BOLL指标UP线。

最后,我们对日线BOLL指标的参数设置技巧和应用原则进行如下总结:1、在价格的日K线BOLL指标参数设置中,参数设得越大,越能反映价格的中长期走势,参数越小,越能反映价格的中短期走势。

2、对指数和个股而言,一般宜将参数值设大一些,参数25是一个已知的最好的值,但弱势股除外。

3、重新按上述参数值设置而成的BOLL指标,更强调背离现象。当价格创出新高而指标波带开口变窄,应当保持警惕。同理,当价格创出新低而波带开口变窄,应当予以注意,此时往往预示着价格即将见底。
老师向您来求教来了,您看下图我做了一个副图公式,想把买卖点做在主图上显示出来结果就成这样了,哪里需要改正啊!请老师不吝赐教.先谢谢了.

解答:
1,把不想显示的线性的语句变成赋值句。
2,在句子后面加上只显示指标数值不画线的函数即可!

 

哪个是只显示指标数值不画线的函数
净是些指标函数/行情函数等.
请您帮我看看.

VAR1:=(2*CLOSE+HIGH+LOW)/4;
VAR2:=EXPMA(EXPMA(EXPMA(VAR1,4),4),4);
J: (VAR2-REF(VAR2,1))/REF(VAR2,1)*100;
D: MA(J,3);
K: MA(J,1);
DRAWTEXT(J<0 AND REF(J,2)>REF(J,1) AND REF(J,1)<J,LOW,'见血封喉'),COLORFF9900;

问:
1,把不想显示的线性的语句变成赋值句。
2,在句子后面加上只显示指标数值不画线的函数即可!

答:
1,在K,D,J参数输出字符:后面加一个=等于号,作用是不输出数值和线性。
VAR1:=(2*CLOSE+HIGH+LOW)/4;
VAR2:=EXPMA(EXPMA(EXPMA(VAR1,4),4),4);
J: =(VAR2-REF(VAR2,1))/REF(VAR2,1)*100;
D:= MA(J,3);
K: =MA(J,1);
DRAWTEXT(J<0 AND REF(J,2)>REF(J,1) AND REF(J,1)<J,LOW,'见血封喉'),COLORFF9900;
2,在句子后面加上只显示指标数值不画线的函数即可!函数 NODRAW
VAR1:=(2*CLOSE+HIGH+LOW)/4;
VAR2:=EXPMA(EXPMA(EXPMA(VAR1,4),4),4);
J:(VAR2-REF(VAR2,1))/REF(VAR2,1)*100,NODRAW;
D:MA(J,3),NODRAW;
K:MA(J,1),NODRAW;
DRAWTEXT(J<0 AND REF(J,2)>REF(J,1) AND REF(J,1)<J,LOW,'见血封喉'),COLORFF9900;